Μερικές Διαφορικές Εξισώσεις

Εξίσωση θερμότητας ($\partial_{t} u-\sigma \nabla^2 u=0$)

Άπειρο χωρίο

Ψάχνουμε τις φραγμένες λύσεις της παρακάτω Μ.Δ.Ε.


           Clear["Global`*"]
f[x_] :=  Which[0 < x < Pi, 0, x > Pi, 1]
PDE = D[v[x, t], t] == D[v[x, t], {x, 2}]
bound = Derivative[1, 0][v][0, t] == 0
init = v[x, 0] == f[x]


           v[x, t] = X[x] T[t]
D[v[x, t], t] == D[v[x, t], {x, 2}]

Έχουμε τις ακόλουθες Σ.Δ.Ε., που προκύπτουν από την τελευταία σχέση.


            ODEx = X''[x]/X[x] == -λ
ODEt = T'[t]/T[t] == -λ

Ας εξετάσουμε αρχικά την περίπτωση που λ<0.


             Assuming[λ < 0, DSolve[ODEx, X[x], x]]

Η λύση αυτή απορρίπτεται ως μη φραγμένη. Ας δούμε τι γίνεται αν λ=0.


              λ = 0
DSolve[ODEx, X[x], x]
Clear[λ]

Και αυτή είναι μη-φραγμένη (επί ποινή μηδενικότητας), άρα απορρίπτεται. Επομένως λ>0 κι έτσι έχουμε:


               λ = n^2

Από τη $v_x(0,t)=0$ έχουμε `X'(0)==0`, όπερ μάς οδηγεί στο κάτωθι συμπέρασμα:


                ODExSol = DSolve[{ODEx, X'[0] == 0}, X[x], x]

Πάμε τώρα στην άλλη Σ.Δ.Ε.


                 ODEtSol = DSolve[ODEt, T[t], t]


                 X[x] /. Flatten[ODExSol]
X[x_] := Evaluate[%]
T[t] /. Flatten[ODEtSol]
T[t_] := Evaluate[%]
v[x, t]

Το $c_1^2$ ας μην παραξενέψει τον αναγνώστη. Απλά το Mathematica πολλαπλασίασε τις δύο σταθερές που προέκυψαν από τις δύο Σ.Δ.Ε., οι οποίος όμως στην πραγματικότητα διαφέρουν. Όπως έχουμε ξαναπεί και σε άλλες εργασίες, κάθε γραμμικός συνδυασμός $\sum a_n e^{-n^2 t} \cos(n x)$ και $\int a_n e^{-n^2 t} \cos(n x)dn$ ικανοποιεί όλες τις συνθήκες, πλην της αρχικής συνθήκης. Επομένως, ψάχνουμε τους συντελεστές Subscript[a, n], ώστε να ικανοποιείται κι αυτή. Δηλαδή θέλουμε: $\int_{0}^{+\infty} a_n \cos(n x)dn=v_0(x),$ όπου $v_0$ η συνάρτηση πολλαπλού τύπου που μάς δίνεται, ήτοι η f(x): Από τη σχέση $\int_{0}^{+\infty} \cos(n x)\cos(n' x)d x={\frac{\pi}{2}}\delta(n-n')$ (βλ. [3] σελ. 201) έχουμε ότι: $<\int_{0}^{+\infty} a_n \cos(n x)dn,\cos(n' x)>= \Leftrightarrow$ $\int_{0}^{+\infty} a_n <\cos(n x),\cos(n' x)>dn= \Leftrightarrow$ $\int_{0}^{+\infty} a_n \int_{0}^{+\infty} \cos(n x) \cdot \cos(n' x)dx dn= \Leftrightarrow$ $\int_{0}^{+\infty} a_n {\frac{\pi}{2}}\delta(n-n') dn= \Leftrightarrow$ $a_{n'} {\frac{\pi}{2}}= \Leftrightarrow$ $a_{n'} ={\frac{2}{\pi}}\int_{0}^{+\infty}v_ 0 (x)\cos(n' x)dx$ Αν, όμως, γράψουμε τα παρακάτω, το Mathematica δεν βγάζει κάποια απάντηση.


                                  2/Pi Integrate[Cos[n x] f[x], {x, 0, Infinity}]

Αυτό συμβαίνει για τον απλούστατο λόγο ότι το κάτωθι ολοκλήρωμα δεν συγκλίνει. Η διαπίστωση αυτή κάνε την συνάρτηση Δέλτα πιθανώς εμπλεκόμενη. Η εμπλοκή της θα μάς φανερωθεί λαμβάνοντας υπ' όψιν ότι το ${\frac{2}{\pi}}\int_{0}^{+\infty}v_ 0 (x)\cos(n' x)dx$ είναι ο μετασχηματισμός Fourier συνημιτόνου της $v_0$ (βλ. [3] σελ. 202). Επομένως:


                                   a[n_] := FourierCosTransform[f[x], x, n]
a[n]

Έτσι, καταλήγουμε στη λύση μας: $v(x,t)=\int_{0}^{+\infty} (\sqrt{2 \pi } \delta (n)-\frac{\sqrt{\frac{2}{\pi }} \sin (\pi n)}{n}) e^{-n^2 t} \cos(n x)dn$


                                     Clear[v]
v[x_, t_] := 
 Integrate[(Sqrt[2 Pi] DiracDelta[n] - (Sqrt[2/Pi] Sin[n Pi])/
     n) E^(-n^2 t)  Cos[n x], {n, 0, Infinity}]
v[x, t]